User:Danysan/Overpass QA

junction=roundabout

Italian roundabouts without junction=roundabout

Only roads with oneway=yes => Less false positives, more false negatives:

try it yourself in overpass-turbo

[bbox:{{bbox}}][out:json][timeout:30];
way["oneway"="yes"]["highway"]["highway"!="cycleway"]["highway"!="footway"]["highway"!="pedestrian"]["highway"!="platform"]["highway"!="construction"][!"junction"]["name"~"^rot",i];
out geom;

All roads => More false positives, less false negatives:

try it yourself in overpass-turbo

[bbox:{{bbox}}][out:json][timeout:30];
way["highway"]["highway"!="cycleway"]["highway"!="footway"]["highway"!="pedestrian"]["highway"!="platform"]["highway"!="construction"][!"junction"]["name"~"^rot",i];
out geom;

highway=speed_camera

Max speed devices not on a way and without enforcement relation

Inspired by https://github.com/osmandapp/OsmAnd/issues/19501#issuecomment-2844550190

try it yourself in overpass-turbo

[bbox:{{bbox}}][out:json][timeout:225];

node[highway=speed_camera] -> .allnodes;
way[highway](bn.allnodes);
node(w)[highway=speed_camera] -> .exnodes;
relation[enforcement](bn.allnodes);
node(r)[highway=speed_camera] -> .exrnodes;

(.allnodes; - .exrnodes;) -> .sn;
(.sn; - .exnodes;);
out;

Maproulette challenges:

• Germany: https://mpr.lt/c/52030
• Italy: https://mpr.lt/c/52409

Max speed enforcement relations without device

try it yourself in overpass-turbo

[bbox:{{bbox}}][out:json][timeout:225];

rel[type=enforcement][enforcement=maxspeed]->.relations;

foreach .relations -> .relation (
  (
    node(r.relation:"device");
    way(r.relation:"device");
    rel(r.relation:"device");
  )->.elem_device;
  
  
  rel.relation(if:elem_device.count(nodes) == 0);

  out center;
);

ref:corine_land_cover=*

Imported elements without feature tags

try it yourself in overpass-turbo

[out:json][timeout:25];
{{geocodeArea:Emilia Romagna}}->.searchArea;

// Select all elements with only ref:corine_land_cover and store them in .all
way["ref:corine_land_cover"][!"landuse"][!"amenity"][!"man_made"][!"leisure"][!"natural"][!"power"][!"place"][!"tourism"][!"aeroway"](area.searchArea)->.all;

// Select all relations, where one of the ways in variable .all is a member...
rel(bw.all);
// ...and for those relations find all related way members and store them in .b
way(r)->.b;

// Calculate the set difference
( .all; - .b; );

out geom;

amenity=*

Schools/kindergartens in Italy without amenity=*

try it yourself in overpass-turbo

[out:json][timeout:120];
// fetch area to search in
{{geocodeArea:Emilia-Romagna}}->.searchArea;
// gather results
way["building"][!"amenity"][!"disused:amenity"]["name"~"^scuola",i](area.searchArea);
// print results
(._;>;);
out meta;